NSIS使用技巧集合

!include "MUI.nsh"
OutFile "test.exe"
!define MUI_PAGE_CUSTOMFUNCTION_Pre ComponentsPre
!insertmacro MUI_PAGE_COMPONENTS
!insertmacro MUI_PAGE_INSTFILES

!insertmacro MUI_LANGUAGE "Simpchinese"

Section "组件A" SecA
SectionEnd

Section "组件B" SecB
SectionEnd

Section "组件C" SecC
SectionEnd

Function ComponentsPre
; 如果注册表 HKEY_CURRENT_USER\Software\Test 下存在 SecA 键,且其值为 0 ,那么第一个组件默认就不勾选。
; 以下同。
ReadRegStr $0 HKCU "Software\Test" "SecA"
IfErrors +2
StrCmp $0 0 0 +2
SectionSetFlags ${SecA} 0

ReadRegStr $0 HKCU "Software\Test" "SecB"
IfErrors +2
StrCmp $0 0 0 +2
SectionSetFlags ${SecB} 0

ReadRegStr $0 HKCU "Software\Test" "SecC"
IfErrors +2
StrCmp $0 0 0 +2
SectionSetFlags ${SecC} 0

Functionend

如何使用NSIS实现多目录安装设置
有些时候,我们需要让用户设置多个安装目录,如果大家用过 Delphi 就知道了,安装 Delphi 的时候我们可以选择为不同功能的程序(例如共享文件目录,主程序目录,数据库设置程序目录等等)设置不同的安装目录,而这样的功能怎么实现呢,以下为一个很好的例子脚本。

!include "MUI.nsh"

Name "Test App"
OutFile "test.exe"

!insertmacro MUI_PAGE_COMPONENTS
Page custom SetCustom LeaveCustom
!insertmacro MUI_PAGE_INSTFILES

!insertmacro MUI_LANGUAGE "SimpChinese"

;--------------------------------

Section "SectionA" SecA
ReadINIStr $0 "$PLUGINSDIR\test.ini" "Field 4" State
MessageBox MB_OK "SectionA 的安装路径为:$0"
SectionEnd

Section "SectionB" SecB
ReadINIStr $0 "$PLUGINSDIR\test.ini" "Field 5" State
MessageBox MB_OK "SectionB 的安装路径为:$0"
SectionEnd

Section "SectionC" SecC
ReadINIStr $0 "$PLUGINSDIR\test.ini" "Field 6" State
MessageBox MB_OK "SectionC 的安装路径为:$0"
SectionEnd

Function .Oninit
InitPluginsDir
File /oname=$PLUGINSDIR\test.ini ".\test.ini"
FunctionEnd

Function SetCustom
; 判断勾选的组件,并把未勾选组件的安装路径控件设为不可用
SectionGetFlags ${SecA} $0
StrCmp $0 0 0 +2
WriteINIStr "$PLUGINSDIR\test.ini" "Field 4" "Flags" "Disabled"
StrCmp $0 1 0 +2 ; 如果组件勾选了,还需要去掉 Disabled,这两行代码不能省略
WriteINIStr "$PLUGINSDIR\test.ini" "Field 4" "Flags" ""

SectionGetFlags ${SecB} $0
StrCmp $0 0 0 +2
WriteINIStr "$PLUGINSDIR\test.ini" "Field 5" "Flags" "Disabled"
StrCmp $0 1 0 +2
WriteINIStr "$PLUGINSDIR\test.ini" "Field 5" "Flags" ""

SectionGetFlags ${SecC} $0
StrCmp $0 0 0 +2
WriteINIStr "$PLUGINSDIR\test.ini" "Field 6" "Flags" "Disabled"
StrCmp $0 1 0 +2
WriteINIStr "$PLUGINSDIR\test.ini" "Field 6" "Flags" ""

; 预定义组件安装路径
WriteINIStr "$PLUGINSDIR\test.ini" "Field 4" "State" "$ProgramFiles"
WriteINIStr "$PLUGINSDIR\test.ini" "Field 5" "State" "$DeskTop"
WriteINIStr "$PLUGINSDIR\test.ini" "Field 6" "State" "$WinDir"

InstallOptions::initDialog /NOUNLOAD "$PLUGINSDIR\test.ini"
!insertmacro MUI_HEADER_TEXT "选择各组件的安装路径" "必须输入有效路径"
InstallOptions::show
Pop $R0

FunctionEnd

Function LeaveCustom
; 判断用户输入的路径是否合法。

ReadINIStr $0 "$PLUGINSDIR\test.ini" "Field 4" "State"
StrCmp $0 "" +2
IfFileExists "$0\*" +3
MessageBox MB_OK|MB_ICONSTOP "组件 A 的安装路径无效!"
Abort

ReadINIStr $0 "$PLUGINSDIR\test.ini" "Field 5" "State"
StrCmp $0 "" +2
IfFileExists "$0\*" +3
MessageBox MB_OK|MB_ICONSTOP "组件 B 的安装路径无效!"
Abort

ReadINIStr $0 "$PLUGINSDIR\test.ini" "Field 6" "State"
StrCmp $0 "" +2
IfFileExists "$0\*" +3
MessageBox MB_OK|MB_ICONSTOP "组件 C 的安装路径无效!"
Abort
FunctionEnd
; Ini file generated by the HM NIS Edit IO designer.
[Settings]
NumFields=6

[Field 1]
Type=Label
Text=A 组件安装路径:
Left=8
Right=68
Top=6
Bottom=13

[Field 2]
Type=Label
Text=B 组件安装路径:
Left=5
Right=65
Top=44
Bottom=51

[Field 3]
Type=Label
Text=C 组件安装路径:
Left=8
Right=68
Top=82
Bottom=89

[Field 4]
Type=DirRequest
Left=14
Right=253
Top=19
Bottom=32

[Field 5]
Type=DirRequest
Left=14
Right=254
Top=57
Bottom=70

[Field 6]
Type=DirRequest
Left=14
Right=254
Top=94
Bottom=107

NSIS 自定义页面结合组件选择安装

问题:
如何控制一个自定义页面的显示与否,例如把一个”数据库操作”做为一个组件选项,而组件选项的下一页(即自定义页面)就是输入数据库连接信息,但是,当用户没有选择”数据库操作”这个组件时,点下一步仍然会出现输入数据库密码页面,怎样做出一个判断:当用户选择”数据库操作”时,下一页为提示输入数据库密码页面,当用户没有选择”数据库操作”时,下一页为安装页面(MUI_PAGE_INSTFILES),即跳过了提示输入数据库密码页面。
以下是一个脚本例子,没有作数据库操作的内容,把问题简单化。 (顺便测试一下 VNISEdit 的 UBB 代码生成功能,^_^v)

/*---------------------------------------
自定义页面结合组件选择安装测试简单脚本。
-----------------------------------------*/

!include "MUI.nsh"
!include "Sections.nsh"

Name "自定义页面结合组件选择测试"
OutFile "Setup.exe"

!insertmacro MUI_PAGE_COMPONENTS
Page custom PageInitFunc PageLeaveFunc "" # 自定义页面
!insertmacro MUI_PAGE_INSTFILES

!insertmacro MUI_LANGUAGE "SimpChinese" # 设置安装界面语言

ShowInstDetails show # 显示安装进度信息

ReserveFile "io.ini" # 预先打包文件,方便安装加速释放 io.ini
!insertmacro MUI_RESERVEFILE_INSTALLOPTIONS # 预先打包文件,方便安装加速释放

Var SHOW_PAGE # 是否显示自定义页面

Function .onInit
StrCpy $SHOW_PAGE "show" # 初始化设显示自定义页面, 如果你默认不打勾,请用 StrCpy $SHOW_PAGE ""
!insertmacro MUI_INSTALLOPTIONS_EXTRACT "io.ini" # 初始化页面
FunctionEnd

Function PageInitFunc
StrCmp $SHOW_PAGE "show" 0 +2 # 如果没有设置“show”则跳过下面的页面显示
!insertmacro MUI_INSTALLOPTIONS_DISPLAY "io.ini" # 显示页面
FunctionEnd

Function PageLeaveFunc
MessageBox MB_OK "自定义页面离开时操作,即点击下一步后触发的事件"
FunctionEnd

Section "数据库处理(自定义页面)" SEC1
# 所有数据库处理在这里写
MessageBox MB_OK "“数据库处理(自定义页面)”操作内容"
SectionEnd

Section "其他操作" SEC2
# 这里填写其他组件的操作
MessageBox MB_OK "“其他操作”操作内容"
SectionEnd

Function .onSelChange
Push $0
SectionGetFlags ${SEC1} $0 # 检测 SEC1 的选择状态,1为已勾选该组件
IntOp $0 $0 & ${SF_selectED} # 只过滤勾选的状态,Checkbox 的状态可能包含多位
;如果为 1 则设置显示自定义页面
IntCmp $0 ${SF_selectED} showpage
StrCpy $SHOW_PAGE "" # 设置不显示自定义页面
Goto done
showpage:
StrCpy $SHOW_PAGE "show" # 设置显示自定义页面
done:
Pop $0
FunctionEnd
[Settings]
NumFields=7

[Field 1]
Type=label
Text=SQLServer 连接?
Left=0
Right=-1
Top=0
Bottom=9

[Field 2]
Type=Text
Left=40
Right=163
Top=22
Bottom=35

[Field 3]
Type=Text
Left=39
Right=163
Top=43
Bottom=54

[Field 4]
Type=Password
Left=39
Right=163
Top=62
Bottom=75

[Field 5]
Type=Label
Text=密码:
Left=8
Right=36
Top=65
Bottom=75

[Field 6]
Type=Label
Text=账号:
Left=8
Right=38
Top=46
Bottom=56

[Field 7]
Type=Label
Text=服务器:
Left=6
Right=34
Top=27
Bottom=36

实现 NSIS 自定义页面中的控件操作代码
问题:
NSIS 中,自定义页面中,有一个 勾选框 和 一个 目录选择编辑框,能否实现勾选 CheckBox 后,目录选择编辑框 可用,如果不勾选,目录选择编辑框 变为不可用。

问题涉及到 NSIS 中自定义页面中的关于控件的消息传递问题,还有怎样进入回调函数处理的问题。
关于自定义页面的预先声明格式: Page custom [创建函数] [离开函数] [标题]
这里解释一下,关于自定义页面的控件回调处理,原来是在 [离开函数] 中处理的。以下是一个例子。另外,要注意 控件 在自定义页面中要设置 Flags 包含 NOTIFY 属性,才可以令程序在 [离开函数] 中处理相关操作。

/*----------------------------------------/
/ 关于 NSIS 自定义页面控件操作的简单脚本。/
/----------------------------------------*/

!include "MUI.nsh"

Name "test"
OutFile "Setup.exe"

Var hwnd ; 自定义页面的窗口句柄

Page custom PageInitFunc PageLeaveFunc # 自定义页面
!insertmacro MUI_PAGE_INSTFILES

!insertmacro MUI_LANGUAGE "SimpChinese" # 设置安装界面语言

ReserveFile "io.ini" # 预先打包文件,方便安装加速释放 io.ini

Function .onInit
InitPluginsDir
File /oname=$PLUGINSDIR\io.ini "io.ini" ; 释放 io.ini 文件
FunctionEnd

Function PageInitFunc
InstallOptions::initDialog /NOUNLOAD "$PLUGINSDIR\io.ini"
Pop $hwnd ; 获取自定义页面的窗口句柄
InstallOptions::show ; 显示自定义页面
Pop $0
FunctionEnd

Function PageLeaveFunc
ReadINIStr $0 "$PLUGINSDIR\io.ini" "Settings" "State" ; 读取那个控件正在使用 state 就是 Field 后面的序数
StrCmp $0 0 NextBtn ; 点击下一步按钮
StrCmp $0 1 CkBox ; 点击 checkbox -- 1 为控件的 FieldNum
Goto NextBtn
CkBox:
ReadINIStr $0 "$PLUGINSDIR\io.ini" "Field 1" "State" ; 获取checkbox 状态
GetDlgItem $1 $hwnd 1201 ; 控件句柄获取公式 (1200 + field 2 - 1)
EnableWindow $1 $0 ; 设置状态,根据 checkbox
GetDlgItem $1 $hwnd 1202 ; 目录设置按钮为 1200 加 1 后的控件
EnableWindow $1 $0 ; 设置状态,根据 checkbox
; GetDlgItem $1 $hwnd 1203 ; 如果还有控件要处理,公式变为 (1200 + field 3 - 1 + 1) 因为前面多了个浏览按钮,所以要再加 1 ,如此类推
; EnableWindow $1 $0
Abort ; 禁止进入下一页面,因为点击的并不是“下一步”按钮
NextBtn:
FunctionEnd

Section "sec a" SEC1
SectionEnd
[Settings]
NumFields=3

[Field 1]
Type=Checkbox
Text=选我才能使用目录框?
Left=22
Right=109
Top=1
Bottom=17
Flags=NOTIFY
State=1

[Field 2]
Type=DirRequest
Left=114
Right=275
Top=1
Bottom=16

[Field 3]
Type=Checkbox
Text=第3个控件?
Left=133
Right=198
Top=33
Bottom=44

NSIS 自定义页面结合组件选择安装(二)
以前有一个例子是一个在 .onSelChange 中实现实时设定是否显示下一个自定义页面的方法。
http://restools.hanzify.org/blogview.asp?logID=56
但是这种方法需要定义一个变量,而且需要每次点击“组件”的时候都会触发事件,显得过于累赘。下面这个例子是在下一个页面的初始化时检测组件选择,从而达到是否显示自定义页面的效果

/*---------------------------------------
自定义页面结合组件选择安装测试简单脚本。
-----------------------------------------*/

!include "MUI.nsh"
!include "Sections.nsh"

Name "自定义页面结合组件选择测试"
OutFile "Setup.exe"

!insertmacro MUI_PAGE_COMPONENTS
Page custom PageInitFunc PageLeaveFunc "" # 自定义页面
!insertmacro MUI_PAGE_INSTFILES

!insertmacro MUI_LANGUAGE "SimpChinese" # 设置安装界面语言

ShowInstDetails show # 显示安装进度信息

ReserveFile "io.ini" # 预先打包文件,方便安装加速释放 io.ini
!insertmacro MUI_RESERVEFILE_INSTALLOPTIONS # 预先打包文件,方便安装加速释放

Function .onInit
!insertmacro MUI_INSTALLOPTIONS_EXTRACT "io.ini" # 初始化页面
FunctionEnd

Function PageInitFunc
SectionGetFlags ${SEC1} $0 # 检测 SEC1 的选择状态,1为已勾选该组件
IntOp $0 $0 & ${SF_selectED} # 只过滤勾选的状态,Checkbox 的状态可能包含多位
IntCmp $0 ${SF_selectED} showpage hidepage hidepage
showpage:
!insertmacro MUI_INSTALLOPTIONS_DISPLAY "io.ini" # 显示页面
hidepage:
FunctionEnd

Function PageLeaveFunc
MessageBox MB_OK "自定义页面离开时操作,即点击下一步后触发的事件"
FunctionEnd

Section "数据库处理(自定义页面)" SEC1
# 所有数据库处理在这里写
MessageBox MB_OK "“数据库处理(自定义页面)”操作内容"
SectionEnd

Section "其他操作" SEC2
# 这里填写其他组件的操作
MessageBox MB_OK "“其他操作”操作内容"
SectionEnd
[Settings]
NumFields=7

[Field 1]
Type=label
Text=SQLServer 连接?
Left=0
Right=-1
Top=0
Bottom=9

[Field 2]
Type=Text
Left=40
Right=163
Top=22
Bottom=35

[Field 3]
Type=Text
Left=39
Right=163
Top=43
Bottom=54

[Field 4]
Type=Password
Left=39
Right=163
Top=62
Bottom=75

[Field 5]
Type=Label
Text=密码:
Left=8
Right=36
Top=65
Bottom=75

[Field 6]
Type=Label
Text=账号:
Left=8
Right=38
Top=46
Bottom=56

[Field 7]
Type=Label
Text=服务器:
Left=6
Right=34
Top=27
Bottom=36

使用 NSIS 作安装程序时如何检测 SQLServer 的连接正确性
当我们要安装一个后台数据库为 SQLServer 的数据库前台程序时,很多时候无可避免地要涉及到对 SQLServer 后台数据库的初始化设置操作,如何使用 NSIS 对用户输入的连接信息进行验证,然后利用这些连接信息进行数据库操作呢,如下脚本简单的实现了一个数据库连接测试的功能。

/*-----------------------------------------
SQLServer 连接测试脚本,这是最简化的脚本,基本上只做了连接测试,其他的操作,例如 数据库还原操作等等这里都没有实现。
-------------------------------------------*/

!include "MUI.nsh"

Name "SQLServer 连接操作"
OutFile "Setup.exe"

Page custom PageInitFunc PageLeaveFunc "" # 自定义页面
!insertmacro MUI_PAGE_INSTFILES

!insertmacro MUI_LANGUAGE "SimpChinese" # 设置安装界面语言

ShowInstDetails show # 显示安装进度信息

ReserveFile "io.ini" # 预先打包文件,方便安装加速释放 io.ini
!insertmacro MUI_RESERVEFILE_INSTALLOPTIONS # 预先打包文件,方便安装加速释放

Var SERVERNAME # 服务器名 例如: server ; user5 ...... 通常是计算机名
Var LOGINNAME # 登陆名 例如: sa ..... SQLServer 安全性属性那里的用户名
Var LOGINPASSWORD # 登陆密码, 如果你用的是 sa 登陆,这里就要 sa 的密码
Var isql_DIR # isql.exe 的所在位置

Function .onInit
!insertmacro MUI_INSTALLOPTIONS_EXTRACT "io.ini" # 初始化页面
FunctionEnd

Function PageInitFunc
!insertmacro MUI_INSTALLOPTIONS_DISPLAY "io.ini" # 显示页面
FunctionEnd

Function PageLeaveFunc
!insertmacro MUI_INSTALLOPTIONS_READ $SERVERNAME "io.ini" "Field 2" "State"
!insertmacro MUI_INSTALLOPTIONS_READ $LOGINNAME "io.ini" "Field 3" "State"
!insertmacro MUI_INSTALLOPTIONS_READ $LOGINPASSWORD "io.ini" "Field 4" "State"
ReadRegStr $isql_DIR HKLM "SOFTWARE\Microsoft\Microsoft SQL Server\80\Tools\ClientSetup" "SQLPath"
nsExec::ExecToStack `"$isql_DIR\Binn\isql" -S$SERVERNAME -U$LOGINNAME -P$LOGINPASSWORD -Q"select 'ok'" -o$PLUGINSDIR\result.txt`
# 这里只是简单的测试返回值 $0 为 0 则连接通过, 为其他值则连接出错,证明账号密码等参数输入错误, 这里只是很简单的检测,较为安全的操作是读取 result.txt 文件,如果里面第 3 行 显示为 ok 则连接正常且顺利运行了一个 SQL 语句。
Pop $0
StrCmp $0 0 pass
MessageBox MB_OK "连接错误,请重新输入连接信息,否则无法进行后面的操作"
Abort
pass:
MessageBox MB_OK "输入连接信息正确,接下来执行其他操作"
FunctionEnd

Section "-SetupFunc" SEC1
DetailPrint "这里执行你要做的数据库操作"
DetailPrint "isql 可以完成所有数据库操作,请看SQLServer的相关帮助"
SectionEnd
[Settings]
NumFields=7

[Field 1]
Type=label
Text=SQLServer 连接?
Left=0
Right=-1
Top=0
Bottom=9

[Field 2]
Type=Text
Left=40
Right=163
Top=22
Bottom=35

[Field 3]
Type=Text
Left=39
Right=163
Top=43
Bottom=54

[Field 4]
Type=Password
Left=39
Right=163
Top=62
Bottom=75

[Field 5]
Type=Label
Text=密码:
Left=8
Right=36
Top=65
Bottom=75

[Field 6]
Type=Label
Text=账号:
Left=8
Right=38
Top=46
Bottom=56

[Field 7]
Type=Label
Text=服务器:
Left=6
Right=34
Top=27
Bottom=36

如何把安装的卸载程序放到其他目录
问题: 如何把卸载程序放到其他地方而能够正常卸载安装的软件。

当因为特殊原因要把卸载程序写到系统的其他目录时,我们会认为直接就是把 uninst.exe 放到其他目录就可以了,但是实际上,NSIS 在卸载时 $INSTDIR 是指向 uninst.exe 的当前目录的。所以我写了一个例子,首先,用向导生成一个基本脚本,然后修改,以下红色注释的行为修改过的。

如何把安装的卸载程序放到其他目录
问题: 如何把卸载程序放到其他地方而能够正常卸载安装的软件。

当因为特殊原因要把卸载程序写到系统的其他目录时,我们会认为直接就是把 uninst.exe 放到其他目录就可以了,但是实际上,NSIS 在卸载时 $INSTDIR 是指向 uninst.exe 的当前目录的。所以我写了一个例子,首先,用向导生成一个基本脚本,然后修改,以下红色注释的行为修改过的。

; 该脚本使用 HM VNISEdit 脚本编辑器向导产生

; 安装程序初始定义常量
!define PRODUCT_NAME "testapp"
!define PRODUCT_VERSION "1.0"
!define PRODUCT_PUBLISHER "test, Inc."
!define PRODUCT_WEB_SITE "http://testapp.com"
!define PRODUCT_DIR_REGKEY "Software\Microsoft\Windows\CurrentVersion\App Paths\testapp.exe"
!define PRODUCT_REGKEY "Software\testapp" # 创建注册表自己程序的键
!define PRODUCT_UNINST_KEY "Software\Microsoft\Windows\CurrentVersion\Uninstall\${PRODUCT_NAME}"
!define PRODUCT_UNINST_ROOT_KEY "HKLM"

Name "${PRODUCT_NAME} ${PRODUCT_VERSION}"
OutFile "Setup.exe"
LoadLanguageFile "${NSISDIR}\Contrib\Language files\SimpChinese.nlf"
InstallDir "$PROGRAMFILES\testapp"
Icon "${NSISDIR}\Contrib\Graphics\Icons\modern-install.ico"
UninstallIcon "${NSISDIR}\Contrib\Graphics\Icons\modern-uninstall.ico"
InstallDirRegKey HKLM "${PRODUCT_UNINST_KEY}" "UninstallString"
DirText "安装程序将安装 $(^Name) 在下列文件夹。$\r$\n$\r$\n要安装在不同文件夹,单击 [浏览] 并选择其他文件夹。"
ShowInstDetails show
ShowUnInstDetails show

Section "MainSection" SEC01
SetOutPath "$INSTDIR"
SetOverwrite ifnewer
File "/oname=testapp.exe" "C:\Program Files\NSIS\NSIS.exe" # 把 NSIS.exe 改名作为测试例子程序
createDirectory "$SMPROGRAMS\测试安装"
createShortCut "$SMPROGRAMS\测试安装\testapp.lnk" "$INSTDIR\testapp.exe"
SectionEnd

Section -AdditionalIcons
createShortCut "$SMPROGRAMS\测试安装\Uninstall.lnk" "$WINDIR\uninst_testapp.exe" # 卸载程序的路径也要改
SectionEnd

Section -Post
WriteUninstaller "$WINDIR\uninst_testapp.exe" # 把卸载程序放到了 "C:\Windows" ,注意,放到可能造成重复文件的地方,一定要把卸载程序改为特殊的名字,防止给另外的卸载程序覆盖。
WriteRegStr HKLM "${PRODUCT_DIR_REGKEY}" "" "$INSTDIR\testapp.exe"
WriteRegStr HKLM "${PRODUCT_REGKEY}" "" "$INSTDIR" # 写入安装时的安装路径。
WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "DisplayName" "$(^Name)"
WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "UninstallString" "$WINDIR\uninst_testapp.exe" # 卸载程序的路径也要改
WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "DisplayIcon" "$INSTDIR\testapp.exe"
WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "DisplayVersion" "${PRODUCT_VERSION}"
WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "URLInfoAbout" "${PRODUCT_WEB_SITE}"
WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "Publisher" "${PRODUCT_PUBLISHER}"
SectionEnd

Function un.onUninstSuccess
HideWindow
MessageBox MB_ICONINFORMATION|MB_OK "$(^Name) 已成功地从你的计算机移除。"
FunctionEnd

Function un.onInit
MessageBox MB_ICONQUESTION|MB_YESNO|MB_DEFBUTTON2 "你确实要完全移除 $(^Name) ,其及所有的组件?" IDYES +2
Abort
FunctionEnd

Section Uninstall
ReadRegStr $INSTDIR HKLM "${PRODUCT_REGKEY}" ""
# 在注册表中强行读入安装路径到变量 $INSTDIR,因为卸载程序默认只认为自己所在路径为 $INSTDIR 路径
delete "$WINDIR\uninst_testapp.exe" # 卸载程序的路径也要改
delete "$INSTDIR\testapp.exe"

delete "$SMPROGRAMS\测试安装\Uninstall.lnk"
delete "$SMPROGRAMS\测试安装\testapp.lnk"

RMDir "$SMPROGRAMS\测试安装"

RMDir "$INSTDIR"

deleteRegKey ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}"
deleteRegKey HKLM "${PRODUCT_DIR_REGKEY}"
SetAutoClose true
SectionEnd

关于如何打破 NSIS 的 8192 字节限制
所以我写了个插件。打破这个限制。如下:下载插件,附插件源码,里面有例子脚本。在这里先附上例子脚本。
—-已找到更加简单的方法来实现这个功能,请看 [关于打破 NSIS 的 8192 字节限制的更简单方法]
—- 这里作为一个功能测试的另类方法吧。

/*----------------------------------------------/
/ 关于 NSIS 自定义控件写入超过 8192 字节的插件。/
/ 理论上如果控件能够容纳,多大的文本都能放入 /
/----------------------------------------------*/

!include "MUI.nsh"

Name "test"
OutFile "Setup.exe"

SetCompressor lzma ; 设置 lzma 压缩方式

Var hwnd ; 自定义页面的窗口句柄

Page custom PageInitFunc PageLeaveFunc # 自定义页面
!insertmacro MUI_PAGE_INSTFILES

!insertmacro MUI_LANGUAGE "SimpChinese" # 设置安装界面语言

ReserveFile "io.ini" # 预先打包文件,方便安装加速释放 io.ini
ReserveFile "license.txt" # 预先打包文件,方便安装加速释放 io.ini

Function .onInit
InitPluginsDir
File "/oname=$PLUGINSDIR\io.ini" "io.ini" ; 释放 io.ini 文件
File "/oname=$PLUGINSDIR\license.txt" "license.txt" ; 释放 license.txt 文件
FunctionEnd

Function PageInitFunc
InstallOptions::initDialog /NOUNLOAD "$PLUGINSDIR\io.ini"
Pop $hwnd ; 获取自定义页面的窗口句柄
GetDlgItem $1 $hwnd 1200 ; 控件句柄获取公式 (1200 + field 1 - 1)
nsExStr::SetWindowText $1 "$PLUGINSDIR\license.txt" ; 写入一个超过 8012 字节的文件到一个控件,我这里写入的是一个超过 30KB 的文本文件。理论上大小没有限制,只要控件能够接受多大,它就能有多大。
InstallOptions::show ; 显示自定义页面
Pop $0
FunctionEnd

Function PageLeaveFunc
FunctionEnd

Section "sec a" SEC1
SectionEnd
[Settings]
NumFields=1

[Field 1]
Type=Text
Flags=MULTILINE|VSCROLL
State=Text
Left=2
Right=299
Top=3
Bottom=137

nsExStr::SetWindowText 调用格式:
nsExStr::SetWindowText [控件窗口句柄] [想加入控件中的文本文件]
返回值: $0 如果是 0 是正常返回,如果是 1 则执行错误。
抛弃那个 NSIS 的编译特别版吧,实在是限制多多,最大也不过是 8192 字节,对于我来说,那是不能满足的。
有了这个插件,你将可以在任何的控件中放入超大文本,你可以预先打包文件,例如协议之类的文本文件,也可以动态写入一个文本文件,然后调用这个插件来把文本写入一个控件
本来如果这个控件用 VC++ 来写可以很小的,无奈偶的 VC++ 本事实在太差,而 Delphi 的代码却是如此的简单,在 exdll.dll 的基础上只加了不到 10 句,这是 VC++ 无法相比的。而且相信在 lzma 的强大压缩之下,当安装文件越来越大时,这个损耗会越来越小。
尽管如此,偶测试过,用 lzma 算法压缩,安装程序只增加了 28 KB 不到。我想如果要我在 VC++ 里面大费周章,我想我还是增加 28 KB 字节算了。

使用方法:把 nsExStr.dll 文件放到 plugins 中,然后就可以像调用其他插件那样做了。
插件下载: http://restools.hanzify.org/nsis/nsExStr.zip

关于打破 NSIS 的 8192 字节限制的更简单方法
上次那个要做一个插件,花去了二十几个 KB,对于更加节省资源,这里提供一个更简单的方法,无需插件。生成安装文件更加的小。
看来偶的功力还有待提升,否则每次做无用功,还真是无趣呢~~

/*----------------------------------------------/
/ 关于 NSIS 自定义控件写入超过 8192 字节的插件。/
/ 理论上如果控件能够容纳,多大的文本都能放入 /
/----------------------------------------------*/

!include "MUI.nsh"
!include "LogicLib.nsh"

Name "test"
OutFile "Setup.exe"

SetCompressor lzma ; 设置 lzma 压缩方式

Var hwnd ; 自定义页面的窗口句柄

Page custom PageInitFunc "" # 自定义页面
!insertmacro MUI_PAGE_INSTFILES # 安装过程页面

!insertmacro MUI_LANGUAGE "SimpChinese" # 设置安装界面语言

ReserveFile "io.ini" # 预先
© 版权声明
THE END
喜欢就支持一下吧
点赞5 分享
评论 抢沙发

请登录后发表评论

    暂无评论内容