最新消息:

二进制在NSIS中的应用

nsis 永恒心锁 1285浏览 0评论
!include nsDialogs.nsh
!define BIT_CHECK_PROGRAMS 0x00000001
!define BIT_CHECK_DESKTOP 0x00000002
!define BIT_CHECK_TASKBAR 0x00000004
Var Flags
Name Example
OutFile Example.exe
XPStyle on
InstallColors /windows
ShowInstDetails show
Page custom CustomPage.Create
Page instfiles
Section Install
SectionEnd
Function CustomPage.Create
 nsDialogs::Create 1018
 Pop $0
 GetFunctionAddress $R0 onCheckBoxClick
 ${NSD_CreateCheckBox} 0u 0u 100% 8u "Create Startmenu Shortcut"
 Pop $0
 nsDialogs::SetUserData $0 ${BIT_CHECK_PROGRAMS}
 nsDialogs::onClick $0 $R0
 IntOp $R1 $Flags & ${BIT_CHECK_PROGRAMS}
 IntCmp $R1 0 +2
 SendMessage $0 ${BM_CLICK} 0 0
 ${NSD_CreateCheckBox} 0u 12u 100% 8u "Create Desktop Shortcut"
 Pop $0
 nsDialogs::SetUserData $0 ${BIT_CHECK_DESKTOP}
 nsDialogs::onClick $0 $R0
 IntOp $R1 $Flags & ${BIT_CHECK_DESKTOP}
 IntCmp $R1 0 +2
 SendMessage $0 ${BM_CLICK} 0 0
 ${NSD_CreateCheckBox} 0u 24u 100% 8u "Create Taskbar Shortcut"
 Pop $0
 nsDialogs::SetUserData $0 ${BIT_CHECK_TASKBAR}
 nsDialogs::onClick $0 $R0
 IntOp $R1 $Flags & ${BIT_CHECK_TASKBAR}
 IntCmp $R1 0 +2
 SendMessage $0 ${BM_CLICK} 0 0
 nsDialogs::Show
FunctionEnd
Function onCheckBoxClick
 Exch $R0
 Push $R1
 Push $R2
 SendMessage $R0 ${BM_GETCHECK} 0 0 $R1
 nsDialogs::GetUserData $R0
 Pop $R2
 IntCmp $R1 ${BST_UNCHECKED} +3
 IntOp $Flags $Flags | $R2
 Goto +3
 IntOp $R2 $R2 ~
 IntOp $Flags $Flags & $R2
 Pop $R2
 Pop $R1
 Pop $R0
FunctionEnd
Function .onInstSuccess
 IntOp $R0 $Flags & ${BIT_CHECK_PROGRAMS}
 IntCmp $R0 0 +2
 MessageBox MB_OK|MB_ICONINFORMATION "Startmenu shortcut!"
 IntOp $R0 $Flags & ${BIT_CHECK_DESKTOP}
 IntCmp $R0 0 +2
 MessageBox MB_OK|MB_ICONINFORMATION "Desktop shortcut!"
 IntOp $R0 $Flags & ${BIT_CHECK_TASKBAR}
 IntCmp $R0 0 +2
 MessageBox MB_OK|MB_ICONINFORMATION "Taskbar shortcut!"
FunctionEnd
免责声明:根据《计算机软件保护条例》第十七条规定“为了学习和研究软件内含的设计思想和原理,通过安装、显示、传输或者存储软件等方式使用软件的,可以不经软件著作权人许可,不向其支付报酬。”您需知晓本站所有内容资源均来源于网络,仅供用户交流学习与研究使用,版权归属原版权方所有,版权争议与本站无关,用户本人下载后不能用作商业或非法用途,需在24个小时之内从您的电脑中彻底删除上述内容,否则后果均由用户承担责任;如果您访问和下载此文件,表示您同意只将此文件用于参考、学习而非其他用途,否则一切后果请您自行承担,如果您喜欢该程序,请支持正版软件,购买注册,得到更好的正版服务。丨本站为个人博客非盈利性站点,所有软件信息均来自网络,所有资源仅供学习参考研究目的,并不贩卖软件,不存在任何商业目的及用途。丨本文采用知识共享 署名4.0国际许可协议 [BY-NC-SA] 进行授权BY-NC-SA协议进行授权

转载请注明:永恒心锁-分享互联网 » 二进制在NSIS中的应用

发表我的评论
取消评论
表情

Hi,您需要填写昵称和邮箱!

  • 昵称 (必填)
  • 邮箱 (必填)
  • 网址