最新消息:

NSIS 程序互斥函数

nsis 永恒心锁 1557浏览 0评论
/************************
 CheckMutex.nsi
************************/
;NSIS 安装程序与卸载程序互相检查互斥的例子
#定义自己的互斥名称:#
#注意安:装程序不能与卸载程序相同!#
!define MyMutex_Install "MyMutex_Install"
!define MyMutex_UnInstall "MyMutex_UnInstall"

;--------------------------------
;Include Modern UI

!include "MUI.nsh"
!include "LogicLib.nsh"

;--------------------------------
;General

;Name and file
Name "Mutex Test"
OutFile "Mutex.exe"

;--------------------------------
#添加安装页面:#
!insertmacro MUI_PAGE_Welcome
!insertmacro MUI_PAGE_InstFiles
!insertmacro MUI_PAGE_Finish
#添加卸载页面:#
!insertmacro MUI_UNPAGE_Welcome
!insertmacro MUI_UNPAGE_InstFiles
!insertmacro MUI_UNPAGE_Finish

;--------------------------------
;加入语言文件

!insertmacro MUI_LANGUAGE "SimpChinese"

;--------------------------------
;安装程序部分

Function .onInit
InitPluginsDir
Call CreateMutex
FunctionEnd

Function CreateMutex
#检查安装互斥:#
ReCheck:
System::Call 'kernel32::CreateMutexA(i 0, i 0, t "${MyMutex_Install}") i .R1 ?e'
Pop $R0
System::Call 'kernel32::CloseHandle(i R1) i.s'
#检查卸载互斥:#
System::Call 'kernel32::CreateMutexA(i 0, i 0, t "${MyMutex_UnInstall}") i .R3 ?e'
Pop $R2
System::Call 'kernel32::CloseHandle(i R3) i.s'
#判断安装/卸载互斥的存在#
${If} $R0 != 0
MessageBox MB_RetryCancel|MB_ICONEXCLAMATION "安装程序已经运行!" IdRetry ReCheck
Quit
${ElseIf} $R2 != 0
MessageBox MB_RetryCancel|MB_ICONEXCLAMATION "卸载程序已经运行!" IdRetry ReCheck
Quit
${Else}
#创建安装互斥:#
System::Call 'kernel32::CreateMutexA(i 0, i 0, t "${MyMutex_Install}") i .R1 ?e'
Pop $R0
StrCmp $R0 0 +2
Quit
${EndIf}
FunctionEnd

Section Install
SetOutPath $EXEDIR
WriteUninstaller "$EXEDIR\Uninstall.exe"
SectionEnd

;--------------------------------
;卸载程序部分

Function un.onInit
InitPluginsDir
Call un.CreateMutex
FunctionEnd

Function Un.CreateMutex
#检查安装互斥:#
ReCheck:
System::Call 'kernel32::CreateMutexA(i 0, i 0, t "${MyMutex_Install}") i .R1 ?e'
Pop $R0
System::Call 'kernel32::CloseHandle(i R1) i.s'
#检查卸载互斥:#
CheckUnInstall:
System::Call 'kernel32::CreateMutexA(i 0, i 0, t "${MyMutex_UnInstall}") i .R3 ?e'
Pop $R2
System::Call 'kernel32::CloseHandle(i R3) i.s'
#判断安装/卸载互斥的存在#
${If} $R0 != 0
MessageBox MB_RetryCancel|MB_ICONEXCLAMATION "安装程序已经运行!" IdRetry ReCheck
Quit
${ElseIf} $R2 != 0
MessageBox MB_RetryCancel|MB_ICONEXCLAMATION "卸载程序已经运行!" IdRetry ReCheck
Quit
${Else}
#创建卸载互斥:#
System::Call 'kernel32::CreateMutexA(i 0, i 0, t "${MyMutex_UnInstall}") i .R1 ?e'
Pop $R0
StrCmp $R0 0 +2
Quit
${EndIf}
FunctionEnd

Section Uninstall
SetOutPath $EXEDIR
Delete "$EXEDIR\Uninstall.exe"
SectionEnd

#脚本结束!#
免责声明:根据《计算机软件保护条例》第十七条规定“为了学习和研究软件内含的设计思想和原理,通过安装、显示、传输或者存储软件等方式使用软件的,可以不经软件著作权人许可,不向其支付报酬。”您需知晓本站所有内容资源均来源于网络,仅供用户交流学习与研究使用,版权归属原版权方所有,版权争议与本站无关,用户本人下载后不能用作商业或非法用途,需在24个小时之内从您的电脑中彻底删除上述内容,否则后果均由用户承担责任;如果您访问和下载此文件,表示您同意只将此文件用于参考、学习而非其他用途,否则一切后果请您自行承担,如果您喜欢该程序,请支持正版软件,购买注册,得到更好的正版服务。丨本站为个人博客非盈利性站点,所有软件信息均来自网络,所有资源仅供学习参考研究目的,并不贩卖软件,不存在任何商业目的及用途。丨本文采用知识共享 署名4.0国际许可协议 [BY-NC-SA] 进行授权BY-NC-SA协议进行授权

转载请注明:永恒心锁-分享互联网 » NSIS 程序互斥函数

您必须 登录 才能发表评论!